Re: Exporting to AFter Effects

["Halim Negadi" <hnegadi(at)gmail.com>]

On 11/25/06, olivier.jeannel(at)noos.fr <olivier.jeannel(at)noos.fr > wrote:

Thank's a lot for that Andrea ! That's real super ! Thank you !
I'm currently preparing our next project which whatever happen will end in AE. I'm going to soon test your addon .

Thank's again,

Cheers,

Olivier
Felici Andrea a écrit :

Try this.
It is a selfinstall vbs plugin that export camera to a .txt file in the ae 6.5 format. Once exported you have to copy and paste the content of .txt file in AE by selecting the Camera and pasting the copied data.

function XSILoadPlugin( in_reg )
        in_reg.Author = "Andrea Felici"
        in_reg.Name = "Camera to After Effects"
        in_reg.Major = 1
        in_reg.Minor = 0
        in_reg.RegisterCommand "AE_CAMERA","AECamExport"
        in_reg.RegisterMenu siMenuMainFileExportID,"AE_CAMERA_Menu",false,false
        XSILoadPlugin = true
end function

function AE_CAMERA_Init( io_Context )
        dim oCmd
        set oCmd = io_Context.Source
'       Application.LogMessage "Orad CAMERA log called"
        oCmd.Description = "Export camera to After Effects file (must be Cut&Pasted)"
        oCmd.ToolTip = ""
        oCmd.ReturnValue = false
        AE_CAMERA_Init = true
end function

sub AE_CAMERA_Execute(  )
        Application.LogMessage "After Effects CAMERA export started"
'       TODO: Put your code here.

' Copyright Andrea Felici 2004
' version 1.0
'
Const PI = 3.1415926535897932384626433832795
Const inches = 25.4
Dim oFS, oBrowser, oAEFile, oEDL, oProject, oRoot, oProgBar
Dim i, oX, oY, oZ
Dim oFirstF, oLastF, oStep, oRate, oCamera, oInterest, oCurPass,oRenderOpt, oXres, oYres, oPixratio
Dim oFocal, oFilm

        set oFS = createobject("scripting.filesystemobject")
        set oBrowser = XSIUIToolkit.FileBrowser 
        set oProject = ActiveProject
        set oRoot = ActiveSceneRoot

        '       set the title, initial directory and filter for saving .txt file
        oBrowser.DialogTitle = "Save After Effects Camera data file" 
        oBrowser.InitialDirectory = oProject.Path 
        oBrowser.Filter = "After Effects Camera data (*.txt)|*.txt||" 
        oBrowser.ShowSave
        if oBrowser.filepathname = "" then

                logmessage "No file selected. Exit"

        else
                oStep = GetValue ("PlayControl.Step")
                oRate = GetValue  ("PlayControl.Rate")
                oFirstF = GetValue ("PlayControl.In")
                oLastF = GetValue ("PlayControl.Out")

        '       Creat file...
                set oAEfile = oFS.CreateTextFile (oBrowser.filepathname)




                set oCurPass = GetCurrentPass
                msgbox "Pick Camera associated to pass " & vbCrLf & oCurPass, 64
                PickElement siCameraFilter, "Pick Camera",, oCamera
                set oInterest = oCamera.Interest
                oXres = GetValue ( oCurPass & ".RenderOptions.CameraXRes" )
                oYres = GetValue ( oCurPass & ".RenderOptions.CameraYRes" )
                oPixratio = GetValue ( oCurPass & ".RenderOptions.PixelRatio" )

                oAEFile.Writeline ( "Adobe After Effects 6.0 Keyframe Data" )
                oAEFile.Writeline (vbCrLf)
                oAEFile.Writeline (     vbTab & "Units Per Second" & vbTab & oRate )
                oAEFile.Writeline (     vbTab & "Source Width" & vbTab & oXres )
                oAEFile.Writeline (     vbTab & "Source Height" &       vbTab & oYres )
                oAEFile.Writeline (     vbTab & "Source Pixel Aspect Ratio" & vbTab & "1" )
                oAEFile.Writeline (     vbTab & "Comp Pixel Aspect Ratio" & vbTab & oPixratio )

'               Position
                oAEFile.Writeline (vbCrLf)
                oAEFile.Writeline ( "Position" )
                oAEFile.Writeline (     vbTab & "Frame" & vbTab & "X Pixels" & vbTab & "Y Pixels" & vbTab & "Z Pixels" )

                LogMessage "Exporting Position"
                for i = oFirstF to oLastF step 0.5

                        Refresh (i)
                        oX = Round (GetValue ( oCamera & ".kine.global.posx", i ), 4)
                        oY = -1 * Round (GetValue ( oCamera & ".kine.global.posy", i ), 4)
                        oZ = -1 * Round (GetValue ( oCamera & ".kine.global.posz", i ), 4)
                        oAEFile.Writeline (     vbTab & i & vbTab & oX & vbTab & oY & vbTab & oZ )

                next

'               Point of Interest
                oAEFile.Writeline (vbCrLf)
                oAEFile.Writeline ( "Point of Interest" )
                oAEFile.Writeline (     vbTab & "Frame" & vbTab & "X Pixels" & vbTab & "Y Pixels" & vbTab & "Z Pixels" )

                LogMessage "Exporting Point of Interest"
                for i = oFirstF to oLastF step 0.5

                        Refresh (i)
                        oX = Round (GetValue ( oInterest & ".kine.global.posx", i ), 4)
                        oY = -1 * Round (GetValue ( oInterest & ".kine.global.posy", i ), 4)
                        oZ = -1 * Round (GetValue ( oInterest & ".kine.global.posz", i ), 4)
                        oAEFile.Writeline (     vbTab & i & vbTab & oX & vbTab & oY & vbTab & oZ )

                next

'               Roll
                oAEFile.Writeline (vbCrLf)
                oAEFile.Writeline ( "Rotation" )
                oAEFile.Writeline (     vbTab & "Frame" & vbTab & "degrees" )
                LogMessage "Exporting Roll"
                for i = oFirstF to oLastF step 0.5

                        Refresh (i)
                        oZ = -1 * Round (GetValue ( oCamera & ".kine.dircns.roll", i ), 4)
                        oAEFile.Writeline (     vbTab & i & vbTab & oZ )

                next

'               ZOOM
                oAEFile.Writeline (vbCrLf)
                oAEFile.Writeline ( "Zoom" )
                oAEFile.Writeline (     vbTab & "Frame" & vbTab & "Pixels" )
                LogMessage "Exporting Field of View"
                for i = oFirstF to oLastF step 0.5

                        Refresh (i)
                        oFocal = GetValue ( oCamera & ".camera.projplanedist", i)
                        oFilm = GetValue ( oCamera & ".camera.projplanewidth", i ) * inches
                        oZ = Round ( ( oXres * oPixratio ) /  oFilm  * oFocal, 3)
                        oAEFile.Writeline (     vbTab & i & vbTab & oZ )

                next
               
                oAEFile.Writeline (     vbCrLf & vbCrLf)       
                oAEFile.Writeline (     "End of Keyframe Data" )
                oAEFile.Writeline (     vbCrLf )
                               
                oAEFile.Close
                set oAEFile = nothing

        end if

        set oProject = nothing
        set oFS = nothing
        set oBrowser = nothing




end sub

function AE_CAMERA_Menu_Init( io_Context )
        dim oMenu
        set oMenu = io_Context.Source
        oMenu.AddCallbackItem "Camera to After Effects","OnAE_CAMERAMenuClicked"
end function

function OnAE_CAMERAMenuClicked( io_Context )
'       Application.LogMessage "OnAE_CAMERAlogMenuClicked called"
        Application.AECamExport
        >
end function

I hope this help you.

Andrea Felici
RAI Radiotelevisione Italiana
Via Salaria 1033
00138 Roma RM
tel. +39 0636868592
fax +39 068802931
cell. +39 3485269346
Felici (at) RAI < mailto:a.felici(at)rai.it>

-----Original Message-----
From: owner-xsi(at)Softimage.COM [ mailto:owner-xsi(at)Softimage.COM] On Behalf Of olivier.jeannel(at)noos.fr
Sent: Thursday, November 23, 2006 8:25 AM
To: XSI(at)Softimage.COM
Subject: Exporting to AFter Effects

I shall soon need to export (at least) XSI camera to AE.
I just would like to know if there is other possibilities than the script from mindthink ? I had no success with this one, mean the exported camera was wrong. But perhaps I did something wrong.

So, was someone able to export camera to After Effects ?
Thanx for any precious advice.

Olivier
---
Unsubscribe? Mail Majordomo(at)Softimage.COM with the following text in body:
unsubscribe xsi

*****************************************************************
Questa e-mail, ed i suoi eventuali allegati, contengono informazioni confidenziali
e riservate. Se avete ricevuto questa comunicazione per errore non utilizzatene
il contenuto e non portatelo a conoscenza di alcuno. Siete inoltre pregati di elimi-
narla dalla vostra casella e avvisare il mittente. E' da rilevare inoltre che l'attuale
infrastruttura tecnologica non puo' garantire l'autenticita' del mittente, ne' tanto-
meno l'integrita' dei contenuti.Opinioni, conclusioni ed altre informazioni contenu-
te nel messaggio possono rappresentare punti di vista personali a meno di diversa
esplicita indicazione autorizzata.
*****************************************************************